用VBA查找最后一个已使用的单元格

xiaoxiaota

http://www.excel123.cn/Article/excelvba/200901/210.html

  如果需要查找区域中最后一个已使用的单元格或表格中已使用的最后一行，可以用下面的VBA代码：
    1.查找某列中最后一个已使用的单元格
    假如要查找第一列中最后一个已使用的单元格，下面的代码可以选择该单元格：
    Sub LastCellInColumn()
        Range("A65536").End(xlUp).Select
    End Sub
    如果第一列数据中包含空格，查找空格**的单元格：
    Sub LastCellBeforeBlankInColumn()
        Range("A1").End(xlDown).Select
    End Sub
    2.查找某行中最后一个已使用的单元格
    假如要查找第一行中最后一个已使用的单元格，可以用下面的代码：
    Sub LastCellInRow()
        Range("IV1").End(xlToLeft).Select
    End Sub
    如果第一行数据中包含空格，查找空格左方的单元格：
    Sub LastCellBeforeBlankInRow()
        Range("A1").End(xlToRight).Select
    End Sub
    3.查找表格中已使用的最后一行
    Sub FindLastRow()
    Dim LastRow As Long
        If WorksheetFunction.CountA(Cells) > 0 Then
        LastRow = Cells.Find(What:="*", After:=[A1], _
            SearchOrder:=xlByRows, SearchDirection:=xlPrevious).Row
            MsgBox "已使用的最后一行是第" & LastRow & "行"
        End If
    End Sub
    4.查找表格中已使用的最后一列
    Sub FindLastColumn()
    Dim LastColumn As Integer
        If WorksheetFunction.CountA(Cells) > 0 Then
            LastColumn = Cells.Find(What:="*", After:=[A1], _
            SearchOrder:=xlByColumns, SearchDirection:=xlPrevious).Column
           MsgBox "已使用的最后一列是第" & LastColumn & "列"
        End If
    End Sub
    5.选择表格中已使用的区域
    Sub SelectUsedRange()
        ActiveSheet.UsedRange.Select
    End Sub
    6.查找已使用区域中的最后一个单元格
    Sub FindLastCellInUsedRange()
    Dim LastColumn As Integer
    Dim LastRow As Long
    Dim LastCell As Range
        If WorksheetFunction.CountA(Cells) > 0 Then
            LastRow = Cells.Find(What:="*", After:=[A1], _
            SearchOrder:=xlByRows, SearchDirection:=xlPrevious).Row
            LastColumn = Cells.Find(What:="*", After:=[A1], _
            SearchOrder:=xlByColumns, SearchDirection:=xlPrevious).Column
            MsgBox "已使用区域中的最后一个单元格是" & Cells(LastRow, LastColumn).Address
        End If
    End Sub